From a532cc245c1338566f5d79c3a3e5a4fbf0a43d5a Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Manuel=20H=C3=BCsers?= <aur@huesers.de>
Date: Wed, 19 Apr 2023 22:50:00 +0200
Subject: [PATCH] upgpkg: ntfs2btrfs-git 20220812.r10.gb8ae0f8-1

* PKGBUILD refactor to be same as non-git package
* new versioning scheme
---
 .SRCINFO   | 21 ++++++++++++++-------
 .gitignore |  4 ----
 PKGBUILD   | 49 +++++++++++++++++++++++++------------------------
 3 files changed, 39 insertions(+), 35 deletions(-)
 delete mode 100644 .gitignore

diff --git a/.SRCINFO b/.SRCINFO
index f9a12f9..fd085fc 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,13 +1,20 @@
 pkgbase = ntfs2btrfs-git
-	pkgdesc = Convertion from ntfs to btrfs keeping NT metadata
-	pkgver = r220.7664363
+	pkgdesc = In-place conversion of Microsoft's NTFS filesystem to the open-source filesystem Btrfs
+	pkgver = 20220812.r10.gb8ae0f8
 	pkgrel = 1
-	arch = any
-	license = GPL
+	url = https://github.com/maharmstone/ntfs2btrfs
+	arch = x86_64
+	license = GPL2
+	makedepends = git
 	makedepends = cmake
-	makedepends = gcc
+	makedepends = pkgconf
 	depends = fmt
-	source = git+https://github.com/maharmstone/ntfs2btrfs
-	md5sums = SKIP
+	depends = zlib
+	depends = lzo
+	depends = zstd
+	provides = ntfs2btrfs
+	conflicts = ntfs2btrfs
+	source = git+https://github.com/maharmstone/ntfs2btrfs.git
+	sha256sums = SKIP
 
 pkgname = ntfs2btrfs-git
diff --git a/.gitignore b/.gitignore
deleted file mode 100644
index 17864e6..0000000
--- a/.gitignore
+++ /dev/null
@@ -1,4 +0,0 @@
-ntfs2btrfs/
-pkg/
-src/
-*pkg.tar*
diff --git a/PKGBUILD b/PKGBUILD
index 9ccf8ba..9ef8d3d 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,34 +1,35 @@
-# Maintainer: N Fytilis <n-fit AT live.com>
-_pkgbase=ntfs2btrfs
-pkgname=$_pkgbase-git
-pkgbase=$_pkgbase-git
-pkgver=r220.7664363
+# Maintainer: Manuel Hüsers <aur@huesers.de>
+# Contributor: N Fytilis <n-fit AT live.com>
+
+pkgname=ntfs2btrfs-git
+pkgver=20220812.r10.gb8ae0f8
 pkgrel=1
-epoch=
-pkgdesc="Convertion from ntfs to btrfs keeping NT metadata"
-arch=(any)
-url=""
-license=('GPL')
-depends=(fmt)
-makedepends=(cmake gcc)
-source=("git+https://github.com/maharmstone/ntfs2btrfs")
-md5sums=(SKIP)
+pkgdesc="In-place conversion of Microsoft's NTFS filesystem to the open-source filesystem Btrfs"
+arch=('x86_64')
+url="https://github.com/maharmstone/${pkgname%-git}"
+license=('GPL2')
+depends=('fmt' 'zlib' 'lzo' 'zstd')
+makedepends=('git' 'cmake' 'pkgconf')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("git+${url}.git")
+sha256sums=('SKIP')
 
 pkgver() {
-  cd "$_pkgbase"
-  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+	cd "${pkgname%-git}"
+	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/release-//g;s/-/./g'
 }
 
 build() {
-  cd "$_pkgbase"
-  mkdir b || true
-  cd b
-  cmake -DCMAKE_INSTALL_PREFIX='/usr' ..
-  make
+	cmake -B build -S "${pkgname%-git}" \
+		-DCMAKE_INSTALL_PREFIX=/usr \
+		-DCMAKE_INSTALL_SBINDIR=bin \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DBUILD_TESTING=OFF
+
+	cmake --build build
 }
 
 package() {
-  cd "$_pkgbase/b"
-  make DESTDIR="$pkgdir/" install
-  mv $pkgdir/usr/sbin $pkgdir/usr/bin
+	DESTDIR="$pkgdir" cmake --install build
 }