pkgname=cage-vi
_pkgname=${pkgname%%-*}
pkgver=0.1.4+54+gbd5b20e
_pkgver=${pkgver%%+*}
pkgrel=1
pkgdesc='A Wayland kiosk, with virtual input patch applied'
arch=('x86_64')
url="https://www.hjdskes.nl/projects/${_pkgname}/"
license=('MIT')
depends=('glibc' 'wayland' 'wlroots')
makedepends=('meson' 'pixman' 'scdoc' 'wayland-protocols' 'xorg-xwayland')
optdepends=(
	'polkit: System privilege control. Required if not using seatd service'
	'xorg-xwayland: X11 support'
)
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=(
	"https://github.com/Hjdskes/${_pkgname}/releases/download/v${_pkgver}/${_pkgname}-${_pkgver}.tar.gz"
	'bd5b20e.patch'
)
sha512sums=('55773fac44bf9e98086e53cbc20d17e3aad7046bedfe638ef8f896543388481be3989fede6f950d4f8cb0583f701cbf79617dfa011c7777a7c8b22c9bcddd64f'
            'e30d9596bf12a793e744a170dc859224f62d807bfc1f980ad26044ffe6170bedd1a1e8a9e9321b3bffb93aa3d42a152e67f60dd6735c6e13a4a2b987131a3394')

#pkgver() {
#	cd "${srcdir}/${_pkgname}-${_pkgver}"
#	git describe --long --tags | sed 's/^v//;s/-/+/g'
#}


prepare() {
	cd "${srcdir}/${_pkgname}-${_pkgver}"
	patch -Np1 -i '../bd5b20e.patch'
	meson --buildtype=release -Dxwayland=true --prefix /usr "$srcdir/build"
}

build() {
	cd "${srcdir}/${_pkgname}-${_pkgver}"
	ninja -C "$srcdir/build"
}

package() {
	cd "${srcdir}/${_pkgname}-${_pkgver}"
	DESTDIR="$pkgdir/" ninja -C "$srcdir/build" install
}