pkgname=cage-vi
_pkgname=${pkgname%%-*}
pkgver=0.1.4+39+ga81ab70
_pkgver=${pkgver%%+*}
pkgrel=1
pkgdesc='A Wayland kiosk, with virtual input patch applied'
arch=('x86_64')
url="https://www.hjdskes.nl/projects/${_pkgname}/"
license=('MIT')
depends=('glibc' 'wayland' 'wlroots')
makedepends=('meson' 'pixman' 'scdoc' 'wayland-protocols' 'xorg-xwayland')
optdepends=(
	'polkit: System privilege control. Required if not using seatd service'
	'xorg-xwayland: X11 support'
)
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=(
	"https://github.com/Hjdskes/${_pkgname}/releases/download/v${_pkgver}/${_pkgname}-${_pkgver}.tar.gz"
	'a81ab70.patch'
	'virtual_input.patch'
)
sha256sums=(
	'dfe27fb0c7d43db72d6c82f01e2736580a0791a23ba69d7b56285d08af98ad90'
	'8580568cc9b68b33de206a841e2110be14de730356c504b66fe366912d0abf76'
	'352a3f33c2690a401c90c4de668d38e4cdff53db6c2fc9577a7c607d8a9ec369'
)

prepare() {
	cd "${srcdir}/${_pkgname}-${_pkgver}"
	patch -Np1 -i '../a81ab70.patch'
	patch -Np1 -i '../virtual_input.patch'
	meson --buildtype=release -Dxwayland=true --prefix /usr "$srcdir/build"
}

build() {
	cd "${srcdir}/${_pkgname}-${_pkgver}"
	ninja -C "$srcdir/build"
}

package() {
	cd "${srcdir}/${_pkgname}-${_pkgver}"
	DESTDIR="$pkgdir/" ninja -C "$srcdir/build" install
}