upgpkg: ntfs2btrfs-git 20220812.r10.gb8ae0f8-1

* PKGBUILD refactor to be same as non-git package
* new versioning scheme

ntfs2btrfs-git/.SRCINFO

@@ -1,13 +1,20 @@
 pkgbase = ntfs2btrfs-git
-	pkgdesc = Convertion from ntfs to btrfs keeping NT metadata
+	pkgdesc = In-place conversion of Microsoft's NTFS filesystem to the open-source filesystem Btrfs
-	pkgver = r220.7664363
+	pkgver = 20220812.r10.gb8ae0f8
 	pkgrel = 1
-	arch = any
+	url = https://github.com/maharmstone/ntfs2btrfs
-	license = GPL
+	arch = x86_64
+	license = GPL2
+	makedepends = git
 	makedepends = cmake
-	makedepends = gcc
+	makedepends = pkgconf
 	depends = fmt
-	source = git+https://github.com/maharmstone/ntfs2btrfs
+	depends = zlib
-	md5sums = SKIP
+	depends = lzo
+	depends = zstd
+	provides = ntfs2btrfs
+	conflicts = ntfs2btrfs
+	source = git+https://github.com/maharmstone/ntfs2btrfs.git
+	sha256sums = SKIP
 
 pkgname = ntfs2btrfs-git

ntfs2btrfs-git/.gitignore

@@ -1,4 +0,0 @@
-ntfs2btrfs/
-pkg/
-src/
-*pkg.tar*

ntfs2btrfs-git/PKGBUILD

@@ -1,34 +1,35 @@
-# Maintainer: N Fytilis <n-fit AT live.com>
+# Maintainer: Manuel Hüsers <aur@huesers.de>
-_pkgbase=ntfs2btrfs
+# Contributor: N Fytilis <n-fit AT live.com>
-pkgname=$_pkgbase-git
+
-pkgbase=$_pkgbase-git
+pkgname=ntfs2btrfs-git
-pkgver=r220.7664363
+pkgver=20220812.r10.gb8ae0f8
 pkgrel=1
-epoch=
+pkgdesc="In-place conversion of Microsoft's NTFS filesystem to the open-source filesystem Btrfs"
-pkgdesc="Convertion from ntfs to btrfs keeping NT metadata"
+arch=('x86_64')
-arch=(any)
+url="https://github.com/maharmstone/${pkgname%-git}"
-url=""
+license=('GPL2')
-license=('GPL')
+depends=('fmt' 'zlib' 'lzo' 'zstd')
-depends=(fmt)
+makedepends=('git' 'cmake' 'pkgconf')
-makedepends=(cmake gcc)
+provides=("${pkgname%-git}")
-source=("git+https://github.com/maharmstone/ntfs2btrfs")
+conflicts=("${pkgname%-git}")
-md5sums=(SKIP)
+source=("git+${url}.git")
+sha256sums=('SKIP')
 
 pkgver() {
-  cd "$_pkgbase"
+	cd "${pkgname%-git}"
-  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/release-//g;s/-/./g'
 }
 
 build() {
-  cd "$_pkgbase"
+	cmake -B build -S "${pkgname%-git}" \
-  mkdir b || true
+		-DCMAKE_INSTALL_PREFIX=/usr \
-  cd b
+		-DCMAKE_INSTALL_SBINDIR=bin \
-  cmake -DCMAKE_INSTALL_PREFIX='/usr' ..
+		-DCMAKE_BUILD_TYPE=Release \
-  make
+		-DBUILD_TESTING=OFF
+
+	cmake --build build
 }
 
 package() {
-  cd "$_pkgbase/b"
+	DESTDIR="$pkgdir" cmake --install build
-  make DESTDIR="$pkgdir/" install
-  mv $pkgdir/usr/sbin $pkgdir/usr/bin
 }