Add 'sublime-text-4/' from commit '499edeb25f'

git-subtree-dir: sublime-text-4
git-subtree-mainline: b1ad5a3f48
git-subtree-split: 499edeb25f

sublime-text-4/PKGBUILD

@@ -0,0 +1,40 @@
+# Maintainer: Manuel Hüsers <aur@huesers.de>
+
+pkgname=sublime-text-4
+pkgver=4.4126
+pkgrel=1
+pkgdesc="Sophisticated text editor for code, html and prose - stable build"
+arch=('x86_64' 'aarch64')
+url="https://www.sublimetext.com/download"
+license=('custom')
+depends=('libpng' 'gtk3')
+optdepends=('gksu: sudo-save support')
+conflicts=('sublime-text')
+provides=('sublime-text')
+install=${pkgname}.install
+
+source=('sublime_text.desktop')
+source_x86_64=("https://download.sublimetext.com/sublime_text_build_${pkgver:2}_x64.tar.xz")
+source_aarch64=("https://download.sublimetext.com/sublime_text_build_${pkgver:2}_arm64.tar.xz")
+
+sha256sums=('e991aac5207655dadf69c6f74c194c80009fb9767d7710337f586908969aa9cf')
+sha256sums_x86_64=('5c64e534cce0032e54d3c7028e8d6b3bdef28f3fd28a26244a360a2ce75450a1')
+sha256sums_aarch64=('0ad4ac168d47034c47ab31faaa0d8b6b4f27e233ea4e48634b930bf999efb63e')
+
+package() {
+  cd "${srcdir}"
+
+  install -dm755 "${pkgdir}/opt"
+  cp --preserve=mode -r "sublime_text" "${pkgdir}/opt/sublime_text"
+
+  for res in 128x128 16x16 256x256 32x32 48x48; do
+    install -dm755 "${pkgdir}/usr/share/icons/hicolor/${res}/apps"
+    ln -s "/opt/sublime_text/Icon/${res}/sublime-text.png" "${pkgdir}/usr/share/icons/hicolor/${res}/apps/sublime-text.png"
+  done
+
+  install -dm755 "${pkgdir}/usr/share/applications"
+  install -Dm644 "sublime_text.desktop" "${pkgdir}/usr/share/applications/sublime_text.desktop"
+
+  install -dm755 "${pkgdir}/usr/bin"
+  ln -s "/opt/sublime_text/sublime_text" "${pkgdir}/usr/bin/subl"
+}