ect: Add sha512 checksums

upstream release

.SRCINFO

@@ -1,16 +1,19 @@
 pkgbase = ect
-	pkgdesc = file compressor, supports postcompression of PNG, JPEG, GZIP and ZIP files.
-	pkgver = 0.9.4
+	pkgdesc = File compressor, supports postcompression of PNG, JPEG, GZIP and ZIP files
+	pkgver = 0.9.5
 	pkgrel = 1
-	url = https://github.com/fhanau/Efficient-Compression-Tool
-	arch = i686
+	url = https://github.com/fhanau/efficient-compression-tool
 	arch = x86_64
 	license = Apache
 	makedepends = nasm
 	makedepends = git
 	makedepends = cmake
 	depends = gcc-libs
-	source = git+https://github.com/fhanau/Efficient-Compression-Tool.git#commit=503409a4de166ad1544adcb5d4e48fef308a2727
-	md5sums = SKIP
+	source = git+https://github.com/fhanau/efficient-compression-tool.git#tag=v0.9.5
+	source = git+https://github.com/glennrp/libpng.git#commit=f135775ad4e5d4408d2e12ffcc71bb36e6b48551
+	source = git+https://github.com/fhanau/mozjpeg.git#commit=182457e3e26e1e078d5dbd09137cf04865be2e49
+	sha512sums = a1d0ad86aa8e6d720575daf7e833c3b787ac51595774b99b6fd4a8ece616150c2e2c174aa97a2bc0b89e16d6cd93ec0c0d657430c1a41bf08b121368af0a4abc
+	sha512sums = 13e286cf091b284d15888a959a8be5a90977bed92d861fd72d465199bd6112641b47d74a525d4100868d528a25921958e9ab579643b705befe48e5756ffa301f
+	sha512sums = 2d3f96c90cfa355797c4ebed9e5568d53f7fe7a1a225007908ea356c0a808cef856004b411b91beb2311102c3c77ea2eed37f3b8b2a9c057b8905c1d21d06383
 
 pkgname = ect

PKGBUILD

@@ -1,38 +1,41 @@
+# Maintainer: Manuel Hüsers <aur@huesers.de>
+# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
 # Contributor: William J. Bowman <aur@williamjbowman.com>
-# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
 
 pkgname=ect
-_pkgname=Efficient-Compression-Tool
-pkgver=0.9.4
+_pkgname=efficient-compression-tool
+pkgver=0.9.5
 pkgrel=1
-pkgdesc='file compressor, supports postcompression of PNG, JPEG, GZIP and ZIP files.'
-url='https://github.com/fhanau/Efficient-Compression-Tool'
-arch=('i686' 'x86_64')
+pkgdesc='File compressor, supports postcompression of PNG, JPEG, GZIP and ZIP files'
+url="https://github.com/fhanau/$_pkgname"
+arch=('x86_64')
 license=('Apache')
-source=("git+$url.git#commit=503409a4de166ad1544adcb5d4e48fef308a2727")
-md5sums=('SKIP')
 depends=('gcc-libs')
 makedepends=('nasm' 'git' 'cmake')
+source=("git+$url.git#tag=v$pkgver"
+	'git+https://github.com/glennrp/libpng.git#commit=f135775ad4e5d4408d2e12ffcc71bb36e6b48551'
+	'git+https://github.com/fhanau/mozjpeg.git#commit=182457e3e26e1e078d5dbd09137cf04865be2e49')
+sha512sums=('a1d0ad86aa8e6d720575daf7e833c3b787ac51595774b99b6fd4a8ece616150c2e2c174aa97a2bc0b89e16d6cd93ec0c0d657430c1a41bf08b121368af0a4abc'
+            '13e286cf091b284d15888a959a8be5a90977bed92d861fd72d465199bd6112641b47d74a525d4100868d528a25921958e9ab579643b705befe48e5756ffa301f'
+            '2d3f96c90cfa355797c4ebed9e5568d53f7fe7a1a225007908ea356c0a808cef856004b411b91beb2311102c3c77ea2eed37f3b8b2a9c057b8905c1d21d06383')
 
 prepare() {
-  cd ${_pkgname}
-  git submodule init 
-  git submodule update --init --recursive --recommend-shallow
+	cd "$_pkgname"
+	git submodule init
+	git config submodule.src/libpng.url "$srcdir"/libpng
+	git config submodule.src/mozjpeg.url "$srcdir"/mozjpeg
+	git -c protocol.file.allow=always submodule update
 }
 
 build() {
-  cd ${_pkgname}
-  [ -d build ] || mkdir build
-  cd build
-  cmake -DECT_FOLDER_SUPPORT=off ../src
-  make
+	cmake -B build -S "$_pkgname"/src \
+		-DCMAKE_INSTALL_PREFIX=/usr \
+		-DCMAKE_BUILD_TYPE=Release
+	cmake --build build
 }
 
 package() {
-  cd ${_pkgname}/build
-  install -Dm755 ect "$pkgdir"/usr/bin/ect 
-  cd "${pkgdir}"/usr/bin
-
-  # Some things expect this to be an all-caps name
-  ln -s ect ECT
+	DESTDIR="$pkgdir" cmake --install build
+	# Some things expect this to be an all-caps name
+	ln -s ect "$pkgdir"/usr/bin/ECT
 }