upgpkg: tuned-git 2.24.1.r0.g90c24ee-1

upstream release
Remove unnecessary sed instruction and options variable due to upstream changes

.SRCINFO

@@ -1,33 +1,49 @@
 pkgbase = tuned-git
 	pkgdesc = Daemon that performs monitoring and adaptive configuration of devices in the system
-	pkgver = 2.10.0.r75.g26db89d
-	pkgrel = 4
+	pkgver = 2.24.1.r0.g90c24ee
+	pkgrel = 1
 	url = https://github.com/redhat-performance/tuned
-	install = tuned.install
 	arch = any
-	license = GPL
-	makedepends = git
+	license = GPL-2.0-or-later
 	makedepends = desktop-file-utils
+	makedepends = git
 	depends = ethtool
-	depends = python-configobj
-	depends = python-pyudev
-	depends = python-gobject
-	depends = python-decorator
-	depends = python-dbus
-	depends = python-schedutils
-	depends = python-linux-procfs
-	depends = perf
+	depends = gawk
 	depends = hdparm
 	depends = polkit
-	depends = hicolor-icon-theme
-	optdepends = virt-what
-	optdepends = systemtap
-	optdepends = python-dmidecode
-	optdepends = x86_energy_perf_policy
-	provides = tuned
-	backup = etc/tuned/active_profile
-	source = tuned-git::git://github.com/redhat-performance/tuned
-	sha256sums = SKIP
+	depends = perf
+	depends = python-configobj
+	depends = python-dbus
+	depends = python-gobject
+	depends = python-linux-procfs
+	depends = python-pyudev
+	source = git+https://github.com/redhat-performance/tuned.git
+	sha512sums = SKIP
 
 pkgname = tuned-git
+	optdepends = virt-what: Virtual machine detection
+	optdepends = systemtap: Detailed system monitoring
+	optdepends = tuned-ppd: power-profiles-daemon api translation
+	optdepends = wireless_tools: Wireless device power management
+	optdepends = x86_energy_perf_policy: Energy Performance Bias (EPB) support
+	provides = tuned
+	conflicts = tuned
+	backup = etc/tuned/active_profile
+	backup = etc/tuned/bootcmdline
+	backup = etc/tuned/cpu-partitioning-powersave-variables.conf
+	backup = etc/tuned/cpu-partitioning-variables.conf
+	backup = etc/tuned/post_loaded_profile
+	backup = etc/tuned/profile_mode
+	backup = etc/tuned/realtime-variables.conf
+	backup = etc/tuned/realtime-virtual-guest-variables.conf
+	backup = etc/tuned/realtime-virtual-host-variables.conf
+	backup = etc/tuned/tuned-main.conf
 
+pkgname = tuned-ppd-git
+	pkgdesc = Daemon that allows applications to easily transition to TuneD from power-profiles-daemon (PPD)
+	depends = tuned
+	provides = tuned-ppd
+	provides = power-profiles-daemon
+	conflicts = tuned-ppd
+	conflicts = power-profiles-daemon
+	backup = etc/tuned/ppd.conf

PKGBUILD

@@ -1,37 +1,73 @@
-# Maintainer: Wes Jackson < icebal dot 7 at gmail dot com >
-# Contributor: Tom < reztho at archlinux dot org >
+# Maintainer: Manuel Hüsers <aur@huesers.de>
+# Contributor: Wes Jackson <icebal dot 7 at gmail dot com>
+# Contributor: Iwan Timmer <irtimmer@gmail.com>
+# Contributor: Timothée Ravier <tim at siosm dot fr>
+# Contributor: Tom <reztho at archlinux dot org>
 
-pkgname=tuned-git
-pkgver=2.10.0.r75.g26db89d
-pkgrel=4
+_pkgbase=tuned
+pkgbase="${_pkgbase}-git"
+pkgname=("${_pkgbase}-git" "${_pkgbase}-ppd-git")
+pkgver=2.24.1.r0.g90c24ee
+pkgrel=1
 pkgdesc='Daemon that performs monitoring and adaptive configuration of devices in the system'
 arch=('any')
-url='https://github.com/redhat-performance/tuned'
-license=('GPL')
-depends=('ethtool' 'python-configobj' 'python-pyudev' 'python-gobject' 'python-decorator' 'python-dbus' 'python-schedutils' 'python-linux-procfs' 'perf' 'hdparm' 'polkit' 'hicolor-icon-theme')
-optdepends=('virt-what' 'systemtap' 'python-dmidecode' 'x86_energy_perf_policy')
-makedepends=('git' 'desktop-file-utils')
-provides=('tuned')
-backup=('etc/tuned/active_profile')
-install="${pkgname/-git}.install"
-source=("${pkgname}::git://github.com/redhat-performance/tuned")
-sha256sums=('SKIP')
+url="https://github.com/redhat-performance/${_pkgbase}"
+license=('GPL-2.0-or-later')
+depends=('ethtool' 'gawk' 'hdparm' 'polkit' 'perf' 'python-configobj'
+	'python-dbus' 'python-gobject' 'python-linux-procfs' 'python-pyudev')
+makedepends=('desktop-file-utils' 'git')
+source=("git+${url}.git")
+sha512sums=('SKIP')
 
 pkgver() {
-  cd ${pkgname}
-  local ver=$(git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g')
-  printf "%s\n" "${ver:1}"
+	cd "${_pkgbase}"
+	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/^v//g;s/-/./g'
 }
 
-package() {
-  cd ${pkgname}
+prepare() {
+	cd "${_pkgbase}"
+	mv libexec lib
 
-  make DESTDIR="${pkgdir}" install
-
-  mv "${pkgdir}"/usr/sbin/* "${pkgdir}"/usr/bin/
-  mv "${pkgdir}"/usr/libexec/tuned/* "${pkgdir}"/usr/lib/tuned/
-  rm -r "${pkgdir}"/run "${pkgdir}"/usr/sbin "${pkgdir}"/usr/libexec
-  install -Dm 0644 "${srcdir}"/${pkgname}/tuned.service "${pkgdir}"/usr/lib/systemd/system/tuned.service
+	sed -i 's|/libexec/|/lib/|g' Makefile
+	sed -i 's|/sbin/|/bin/|g' Makefile tuned.service tuned-gui.py tuned-gui.desktop tuned/ppd/tuned-ppd.service
 }
 
-# vim:set ts=2 sw=2 et:
+package_tuned-git() {
+	optdepends=('virt-what: Virtual machine detection'
+		'systemtap: Detailed system monitoring'
+		'tuned-ppd: power-profiles-daemon api translation'
+		'wireless_tools: Wireless device power management'
+		'x86_energy_perf_policy: Energy Performance Bias (EPB) support')
+	provides=("${_pkgbase}")
+	conflicts=("${_pkgbase}")
+	backup=('etc/tuned/active_profile'
+		'etc/tuned/bootcmdline'
+		'etc/tuned/cpu-partitioning-powersave-variables.conf'
+		'etc/tuned/cpu-partitioning-variables.conf'
+		'etc/tuned/post_loaded_profile'
+		'etc/tuned/profile_mode'
+		'etc/tuned/realtime-variables.conf'
+		'etc/tuned/realtime-virtual-guest-variables.conf'
+		'etc/tuned/realtime-virtual-host-variables.conf'
+		'etc/tuned/tuned-main.conf')
+
+	cd "${_pkgbase}"
+
+	make DESTDIR="${pkgdir}" install
+	rm -rv "${pkgdir}"/{run,var}
+
+	python -m compileall -d /usr/lib "${pkgdir}/usr/lib"
+	python -O -m compileall -d /usr/lib "${pkgdir}/usr/lib"
+}
+
+package_tuned-ppd-git() {
+	pkgdesc='Daemon that allows applications to easily transition to TuneD from power-profiles-daemon (PPD)'
+	depends=("${_pkgbase}")
+	provides=("${_pkgbase}-ppd" 'power-profiles-daemon')
+	conflicts=("${_pkgbase}-ppd" 'power-profiles-daemon')
+	backup=('etc/tuned/ppd.conf')
+
+	cd "${_pkgbase}"
+
+	make DESTDIR="${pkgdir}" install-ppd
+}

tuned.install

@@ -1,3 +0,0 @@
-post_install() {
-  systemd-tmpfiles --create tuned.conf
-}