43 lines
1.9 KiB
Bash
43 lines
1.9 KiB
Bash
# Maintainer: Manuel Hüsers <aur@huesers.de>
|
|
# Contributor: Sander Boom <sanderboom@gmail.com>
|
|
# Contributor: realitygaps <realitygaps at yahoo dot com>
|
|
|
|
pkgname=sublime-text-dev
|
|
pkgver=4.4169
|
|
pkgrel=1
|
|
pkgdesc='Sophisticated text editor for code, html and prose - dev build'
|
|
arch=('x86_64' 'aarch64')
|
|
url='https://www.sublimetext.com/dev'
|
|
license=('custom')
|
|
depends=('libpng' 'gtk3')
|
|
conflicts=('sublime-text')
|
|
provides=('sublime-text')
|
|
install=${pkgname}.install
|
|
|
|
source_x86_64=("${pkgname//-/_}_${pkgver/./_}_${pkgrel}_x64.tar.xz::https://download.sublimetext.com/sublime_text_build_${pkgver:2}_x64.tar.xz")
|
|
source_aarch64=("${pkgname//-/_}_${pkgver/./_}_${pkgrel}_arm64.tar.xz::https://download.sublimetext.com/sublime_text_build_${pkgver:2}_arm64.tar.xz")
|
|
|
|
sha512sums_x86_64=('6764363f8f92f65532d64ba014023e28b18f40dc62a1b114239b59360257d445494f9a2f57580174b5f4994c8fa06cd8f562c9419cfda92324c9ebf25d15e576')
|
|
sha512sums_aarch64=('e9964f55a5bff89fc0ad13266cc7695c8e0cc41d86caed212836fd737c3b52d84400c683b3f9699b554e71fa2d3ed3cc4351cfebcf9f182512211227465db3d6')
|
|
|
|
package() {
|
|
cd "${srcdir}"
|
|
|
|
install -dm755 "${pkgdir}/opt"
|
|
cp --preserve=mode -r 'sublime_text' "${pkgdir}/opt/sublime_text"
|
|
rm -f "${pkgdir}/opt/sublime_text/sublime_text.desktop"
|
|
|
|
for res in 128x128 16x16 256x256 32x32 48x48; do
|
|
install -dm755 "${pkgdir}/usr/share/icons/hicolor/${res}/apps"
|
|
ln -s "/opt/sublime_text/Icon/${res}/sublime-text.png" "${pkgdir}/usr/share/icons/hicolor/${res}/apps/sublime-text.png"
|
|
done
|
|
|
|
sed -i 's#/opt/sublime_text/sublime_text#/usr/bin/subl#g' 'sublime_text/sublime_text.desktop'
|
|
sed -i '\#^StartupNotify=#a StartupWMClass=subl' 'sublime_text/sublime_text.desktop'
|
|
|
|
install -dm755 "${pkgdir}/usr/share/applications"
|
|
install -Dm644 'sublime_text/sublime_text.desktop' "${pkgdir}/usr/share/applications/sublime_text.desktop"
|
|
|
|
install -dm755 "${pkgdir}/usr/bin"
|
|
ln -s '/opt/sublime_text/sublime_text' "${pkgdir}/usr/bin/subl"
|
|
}
|